W skrócie, jest to wskaźnik na obiekt który wywołuje dane zdarzenie. Jeśli widzimy to w zdarzeniu OnClick przycisku, to jest to właśnie wskaźnik na ten przycisk (oczywiście trzeba go rzutować na TButton aby odnieść się do jego własności).

Ktoś może zapytać, po co mi coś takiego, skoro dobrze wiem które zdarzenie przypisane jest któremu przyciskowi? Ano po to, że istnieje możliwość przypisania tego samego zdarzenia kilku obiektom, a nie tylko jednemu.

Weźmy prosty przykład, mam na formie 3 przyciski o różnych etykietach. Załóżmy że chcę, po kliknięciu w każdy z nich, aby na belce okna wyświetlała się etykieta tego klikniętego. W tradycyjnym podejściu należało by oprogramować 3 zdarzenia kliknięcia. My zrobimy to w jednym, wykorzystując parametr Sender, oraz przypisując owe zdarzenie do wszystkich przycisków:

procedure TForm1.ButtonClick(Sender: TObject);
begin
  Caption := TButton(Sender).Caption;
end;

I to już wszystko! Przy pierwszym przycisku utworzyłem nowy event (zmieniając nieco jego nazwę), przy kolejnych wybrałem go z rozwijanej listy dla zdarzenia OnClick. Szybko, łatwo i bez zbędnego kodu.

W tym wpisie pokaże jakich błędów unikać pisząc w Delphi skomplikowane działania, aby nie marnować czasu użytkownika końcowego naszej aplikacji. Do dzieła!

Stałe

Zacznijmy od rzeczy najprostszej, wykluczania operacji których wynik jest zawsze taki sam. Głupota? Prosty przykład, obliczenia w których występuje liczba PI podniesiona do kwadratu. Wartość tego wyrażenia jest zawsze taka sama, gdyż PI wynosi zawsze tyle samo.

procedure TForm1.Button1Click(Sender: TObject);
var
  k: Double;
begin
  k := GetTickCount * Sqr(PI) + 4;
end;

W takiej sytuacji zamiast podnosić 3,14 za każdym razem do kwadratu, najlepiej wyliczyć sobie tą wartość chociażby na systemowym kalkulatorze i zadeklarować nową stałą. Rzecz jasna, jak wcześniej wspomniałem, ma to sens tylko gdy wykonujemy naprawdę dużo obliczeń – inaczej jest to sztuka dla sztuki.

procedure TForm1.Button1Click(Sender: TObject);
const
  PI_2 = 9.8696044010893586188344909998762;
var
  k: Double;
begin
  k := GetTickCount * PI_2 + 4;
end;

Unikanie dzielenia

Swego czasu, wyczytałem iż lepiej jest przykładowo mnożyć razy 0,5 niż dzielić przez 2. Próbowałem potwierdzić to różnymi testami, ale za każdym razem dostawałem identyczny wynik. Strzelam że obecne procesory lepiej sobie radzą z dzieleniem w stosunku do mnożenia liczb zmiennoprzecinkowych niż kiedyś.

Dlatego też porada ta nie ma dzisiaj większego sensu, ale warto o niej pamiętać.

Power, Sqr, Sqrt

Funkcja Power, analogicznie do swojej nazwy kryje w sobie dużą moc , nie mniej, należy się jej wystrzegać jak ognia. Power przyjmuje 2 argumenty, pierwszym jest liczba którą chcemy podnieść do potęgi, a drugim wykładnik potęgi.

Daje to ogromne możliwości z uwagi na fakt iż jest to liczba zmiennoprzecinkowa. Nie mniej, w sytuacji w której podnosimy liczbę do potęgi drugiej, bądź wyciągamy pierwiastek stopnia drugiego bezwzględnie stosujmy funkcje Sqr oraz Sqrt. Pierwiastek 4 stopnia? Zagnieżdżone dwie funkcję Sqrt będą na pewno szybsze niż jeden Power.

Oto małe porównanie szybkości wykonywania się poszczególnych operacji:

I na koniec wynik testu z pierwiastkiem czwartego stopnia:

Podsumowanie

Liczę że te kilka porad pozwoli Wam na optymalizację wielokrotnie wykonywanych działań matematycznych w Delphi. Oczywiście należy też pamiętać o doprowadzeniu danego równania do jak najprostszej postaci przed przystąpieniem do implementacji w programie.

TTabControl to komponent w którym operujemy na samych zakładkach, z kolei TPageControl zarządza całymi stronami wraz z przypisaną do nich zawartością.

W TTabControl cała umieszczona zawartość na komponencie jest wspólna dla wszystkich zakładek. Po co nam coś takiego? Otóż w sytuacji w której zmieniają się jedynie dane między zakładkami a nie cały układ komponentów. Załóżmy że mamy naniesiony na owym komponencie wykres wraz z kilkoma przyciskami do jego zarządzania. Na każdej zakładce chcemy zatem mieć te same elementy a zmieniać jedynie zawartość wykresu i akcję przycisków. Możemy to uczynić przy pomocy zdarzenia OnChange.

Dodatkowo, w bardzo łatwy sposób możemy dynamicznie (lub na etapie projektowania) zmieniać ilość zakładek dzięki właściwości Tabs będącej typu TStrings.

W opozycji do w/w komponentu, TPageControl posiada unikalną zawartość każdej zakładki. Jest to wygodne w sytuacji w której chcemy umieścić różne komponenty na każdej stronie.

Kolejne zakładki dodajemy w równie łatwy sposób na etapie projektowania. Są one w odróżnieniu od TPageControl osobnymi komponentami klasy TTabSheet a nie jedynie wpisem na liście.

Komponent ten stosujemy wszędzie tam gdzie każda strona ma inną zawartość, np.: kategorie opcji programu.

Liczę że ten mały poradnik pomoże wszystkich początkującym programistom dostrzec różnicę między tymi komponentami i wybrać ten właściwy, którego w danej sytuacji potrzebują.

Jedyną opcją wykorzystania ikony z kanałem alpha jest wstawienie komponentu TImage i załadowanie do niego pliku ikony. Co jeśli chcemy użyć przeźroczystego obrazka w menu, pasku narzędzi czy zakładce? Tutaj jedynym komponentem który nam to umożliwia jest TImageList, który niestety gubi informacje o kolorach powyżej 24 bitów.

W tym wpisie pokaże jak sobie z tym poradzić i mimo to użyć ładnych plików ikon w naszych aplikacjach.

Rozwiązanie z racji stosowania pewnego tricku ma pewną wadę. Wszystkie zasoby do TImageList musimy ładować w trakcie działania aplikacji a nie na etapie projektowania – innymi słowy, musimy osobno do pliku wykonywalnego dołączać pliki ikon których użyjemy.

Drugą niewygodą, która jest następstwem pierwszej, jest fakt że przypisując konkretnemu elementowi ImageIndex musimy wpisać go nie widząc załadowanej ikony – wymusza to nas nas ładowanie ikon zawsze w tej samej kolejności i trzymania pozycji danego obrazka zawsze pod tym samym numerkiem.

Są to pewne wady który uprzykrzają proces pisania programu, ale jak to mówią, coś za coś.

Przejdźmy zatem do czynów. Mając umieszczony na formie TImageList musimy go dostosować do przyjmowania 32-bitowych ikon. Skorzystajmy z tej oto procedury:

procedure ConvertTo32BitImageList(ImageList: TImageList);
const
  MASK: array[Boolean] of Longint = (0, ILC_MASK);
var
  templist: TImageList;
begin
  if Assigned(ImageList) then
  begin
    templist := TImageList.Create(nil);
    try
      templist.Assign(ImageList);
      with ImageList do
      begin
        Handle := ImageList_Create(Width, Height, ILC_COLOR32 or MASK[Masked], 0, AllocBy);
        if not HandleAllocated then
          raise EInvalidOperation.Create(SInvalidImageList);
      end;
      Imagelist.AddImages(templist);
    finally
      FreeAndNil(templist);
    end;
  end;
end;

Po skonwertowaniu listy obrazów (pustej), możemy zacząć dodawać nasze zasoby. Dla ułatwienia możemy skorzystać z tej procedury:

procedure AddIconTo32BitImageList(ImageList: TImageList; const FileName: String);
var
  icon: TIcon;
  stream: TFileStream;
begin
  icon := TIcon.Create;
  stream := TFileStream.Create(FileName, fmOpenRead);
  icon.LoadFromStream(stream);
  ImageList.AddIcon(icon);
  icon.Free;
  stream.Free;
end;

Jak widać, powyższa procedura przyjmuje 2 parametry, komponent TImageList oraz ścieżkę do ikony którą chcemy dodać. Należy pamiętać o tym aby skonfigurować odpowiednio listę obrazów do naszych potrzeb – ustawić wymiar ikon.

Przykładowe użycie powyższej metody:

procedure TForm1.FormCreate(Sender: TObject);
begin
  ImageList1.Clear;
  ConvertTo32BitImageList(ImageList1);
  AddIconTo32BitImageList(ImageList1, 'data\open.ico');
  AddIconTo32BitImageList(ImageList1, 'data\save.ico');
  AddIconTo32BitImageList(ImageList1, 'data\exit.ico');
end;

warunek ? jeśli_prawda : jeśli_fałsz

Przykładowo:

$zmienna = $k >= 0 ? 'dodatnie' : 'ujemne';

…odpowiada konstrukcji:

if ($k >= 0)
{
  $zmienna = 'dodatnie';
}
else
{
  $zmienna = 'ujemne';
}

Jak widać uproszczenie jest znaczne. Object Pascal (Delphi) nie posiada niestety operatora trójargumentowego. W tym wpisie pokażę jak zastąpić tą funkcjonalność przy pomocy prostej funkcji i jej przeciążenia.

Zasadniczo, naszym zadaniem będzie stworzenie funkcji o 3 argumentach, która będzie odpowiednikiem operatora trójargumentowego. Jako iż nie jest to skomplikowane zadanie, przystąpmy do działania:

function IfThen(Condition: Boolean; const TrueValue: String; const FalseValue: String): String;
begin
  if Condition then Result := TrueValue else Result := FalseValue;
end;

Funkcję tę nazwałem IfThen, gdyż jest to w zasadzie skrót konstrukcji if…then…else. Pierwszym parametrem jest warunek, kolejnym zwracana wartość w przypadku spełnienia owego warunku i ostatnim, wartość w przypadku fałszu.

Jak możemy zauważyć, funkcja dedykowana jest jedynie dla argumentów będących ciągiem znaków. Korzystając z dyrektywy overload, stwórzmy przeciążone funkcje dostosowane do wielu różnych typów zmiennych. Całość, umieściłem od razu w osobnym module w celu łatwiejszego, późniejszego wykorzystania napisanych funkcji.

unit TripleOperator;

interface

function IfThen(Condition: Boolean; TrueValue, FalseValue: Byte): Byte; overload;
function IfThen(Condition: Boolean; TrueValue, FalseValue: Integer): Integer; overload;
function IfThen(Condition: Boolean; TrueValue, FalseValue: Single): Single; overload;
function IfThen(Condition: Boolean; TrueValue, FalseValue: Double): Double; overload;
function IfThen(Condition: Boolean; const TrueValue: String; const FalseValue: String): String; overload;

implementation

function IfThen(Condition: Boolean; TrueValue, FalseValue: Byte): Byte;
begin
  if Condition then Result := TrueValue else Result := FalseValue;
end;

function IfThen(Condition: Boolean; TrueValue, FalseValue: Integer): Integer;
begin
  if Condition then Result := TrueValue else Result := FalseValue;
end;

function IfThen(Condition: Boolean; TrueValue, FalseValue: Single): Single;
begin
  if Condition then Result := TrueValue else Result := FalseValue;
end;

function IfThen(Condition: Boolean; TrueValue, FalseValue: Double): Double;
begin
  if Condition then Result := TrueValue else Result := FalseValue;
end;

function IfThen(Condition: Boolean; const TrueValue: String; const FalseValue: String): String;
begin
  if Condition then Result := TrueValue else Result := FalseValue;
end;

end.

Pobierz TripleOperator.pas.

Tym sposobem, zrealizowaliśmy operator trójargumentowy w Delphi dla kilku typów zmiennych. Jak widać, bardzo łatwo można dodać kolejne. Przykładowe użycie funkcji IfThen:

procedure TForm1.Button1Click(Sender: TObject);
begin
  Caption := IfThen(Top <= 200, 'okno jest nisko', 'okno jest wysoko');
end;

Niestety są pewne kruczki w stosunku do wersji w PHP. Po pierwsze, jest to funkcja a nie składnia języka – ciut mniejsza wydajność. Po drugie, w przypadku spełnienia warunku, oba argumenty muszą zostać przekazane do funkcji, a nie tylko ten odpowiedzialny za prawdę. Innymi słowy, jeśli argumentami są wyniki działań innych funkcji, to bez względu na wynik parametru Condition, i tak obie zostaną wykonane, mimo że zwrócona zostanie tylko jedna z nich. Nie posiada tego mankamentu konstrukcja if…then…else, gdzie po wykonaniu pierwszej instrukcji, blok else w ogóle nie jest analizowany. W zależności od wykorzystania, może to nie mieć znaczenia lub mieć bardzo duże. Przykładowo:

Count := IfThen(i = 0, 8, 8 div i);

Taki przypadek, w sytuacji gdy zmienna i przyjmuje wartość 0, spowoduje niestety błąd.

Wszystko więc zależy od zastosowania, nie mniej, w większości przypadków skraca nam to ilość kodu jaki musielibyśmy napisać tradycyjnie.

Metoda opiera się na dynamicznym tworzeniu instancji komponentu, zatem jest ona zgodna z licencją i nie narusza jej w żaden sposób. Oczywiście niesie to za sobą pewne niedogodności i nie zawsze może być stosowane, jednak w znakomitej większości przypadków tak.

Jako przykład, wykorzystam komponentem THTTPGet, służący do pobierania plików z internetu. Nie jest to komponent wizualny, tzn. udostępnia pewną funkcjonalność a nie element widoczny dla użytkownika końcowego.

W pierwszej kolejności, po umiejscowieniu plików na dysku, musimy dodać wybraną lokalizację do ścieżki przeszukiwania bibliotek. Robimy to w menu Tools > Options > Library – Win32 > Library path. Jeśli ten krok mamy już za sobą, dodajemy do sekcji uses nazwę komponentu:

uses
 Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
 Dialogs, HTTPGet;

Kolejno musimy stworzyć nową instancję komponentu, w zależności od tego czy wykorzystujemy go tylko w określonym fragmencie kodu, czy też globalnie, funkcje tworzenia i zwalnianie umieszczamy w stosownym miejscu. Ja postanowiłem utworzyć komponent zaraz po załadowaniu aplikacji oraz zwolnić go przy jej zamykaniu:

procedure TForm1.FormCreate(Sender: TObject);
begin
  HTTPGet := THTTPGet.Create(Self);
end;

procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  HTTPGet.Free;
end;

HTTPGet to nazwa zmiennej zadeklarowanej w sekcji private klasy TForm1. W tym momencie możemy już korzystać z komponentu, odnosząc się do zmiennej HTTPGet.

To rozwiązanie pozwala nam na swobodę w doborze komponentów w Turbo Delphi Explorer, jednak niesie ze sobą pewne ograniczenia. W przypadku komponentów wizualnych, nie możemy w wygodny sposób umieścić ich na formie oraz manipulować ich wyglądem. Musimy tego dokonać po przez odnoszenie się do odpowiednich właściwości w samym kodzie, najlepiej tuż po jego stworzeniu.

Na koniec zamieszczam całościowy listing kodu wykorzystanego w tym wpisie, wraz z przykładowym zastosowaniem THTTPGet:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, HTTPGet, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure FormCreate(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure Button1Click(Sender: TObject);
  private
    HTTPGet: THTTPGet;
    procedure FileDone(Sender: TObject; FileName: String; FileSize: Integer);
  public
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
  HTTPGet := THTTPGet.Create(Self);
end;

procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  HTTPGet.Free;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  Button1.Enabled := False;
  with HTTPGet do
    begin
    BinaryData := True;
    URL := 'http://downloads.sourceforge.net/sevenzip/7z465.exe';
    FileName := '7z465.exe';
    OnDoneFile := FileDone;
    GetFile;
  end;
end;

procedure TForm1.FileDone(Sender: TObject; FileName: String; FileSize: Integer);
begin
  Button1.Enabled := True;
end;

end.

MD5 (z ang. Message-Digest algorithm 5 – Skrót wiadomości wersja 5) – algorytm z dziedziny kryptografii. Jest to popularna kryptograficzna funkcja skrótu, która z dowolnego ciągu danych generuje 128-bitowy skrót.

Źródło: http://pl.wikipedia.org/wiki/MD5

Język programowania jakim jest Delphi, mimo swojej potęgi nie posiada wbudowanych funkcji do obliczania sum kontrolnych, nawet tak popularnych jak MD5. Nie będę pokazywał jak stworzyć implementację algorytmu MD5 w object pascalu, chociaż jest to możliwe, a zademonstruję jak policzyć sumę kontrolną dowolnego łańcucha z wykorzystaniem pakietu DCPcrypt.

Pakiet DCPcrypt posiada implementację dla bardzo dużej ilości algorytmów mieszających jak i szyfrujących. W tym wpisie zajmiemy się jego niewielką cząstką w postaci sumy MD5. Pierwsze co musimy zrobić to pobrać ów pakiet, można to zrobić na stronie autora kodu, bądź bezpośrednio tutaj. DCPcrypt można zainstalować jako komponent w środowisku Delphi, nie mniej, my ograniczymy się do wypakowania plików i dodania w konfiguracji środowiska ścieżki przeszukiwania bibliotek (Tools > Options > Library – Win32 > Library path). Operację tę przeprowadzamy dla głównego folderu pakietu oraz podfolderu Hashes.

Po wstępnej konfiguracji możemy przejść do napisania pożądanej funkcji. W pierwszej kolejności dodajemy do listy używanych bibliotek (uses) moduł DCPmd5.

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, DCPmd5;

Kolejno deklarujemy funkcję o nazwie MD5, która przyjmuje 1 parametr wejściowy w postaci ciągu znaków, oraz takowy zwraca – jego sumę kontrolną.

function MD5(const S: String): String;
var
  i: Byte;
  digest: array[0..15] of Byte;
begin

  with TDCP_md5.Create(nil) do
  begin
    Init;
    Update(S[1], Length(S));
    Final(digest);
    Free;
  end;

  Result := '';
  for i := 0 to Length(digest)-1 do
    Result := Result + IntToHex(digest[i], 2);
  Result := LowerCase(Result);

end;

Na koniec kilka słów objaśnienia powyższego kodu. Po stworzeniu instancji klasy TDCP_md5, następuje jej inicjacja metodą Init. Metoda Update może być wywoływana dowolną ilość razy i przyjmuje jako parametry bufor ciągu bajtów z którego generowana jest funkcja skrótu, oraz jego długość. W naszym przypadku, podajemy początek ciągu znaków ([1] jest wymagane gdyż zerowym elementem tablicy jakim jest String jest jego długość, co powodowało by błędne obliczenia). Jeśli obliczalibyśmy sumę kontrolną pliku, dobrym zwyczajem jest, aby nie obciążać pamięci, odczytywać fragmentami badany plik oraz obliczać część sumy przy pomocy metody Update. Całościowe odczytanie pliku wymagało by zadeklarowania tyle pamięci RAM ile zajmuje dany plik.

Metoda Final kończy obliczenia i zrzuca sumę w postaci tablicy bajtów. Końcowa pętla przekształca ją do postaci w jakiej jest zwykle używana (np: 0cc1099409f2effa3e09912cda637023 dla ciągu wejściowego bbproject.net).

Jeśli zajedzie potrzeba, powyższy kod bardzo łatwo możemy zmodyfikować na potrzeby choćby sumy SHA-1, lub dowolnej innej obsługiwanej przez DCPcrypt. Dlaczego użyłem akurat tego pakietu, podczas gdy w internecie łatwo znaleźć dziesiątki innych, gotowych implementacji? Powodów jest kilka, po pierwsze szybkość obliczeń, z moich testów wynika iż implementacja wykonana w pakiecie DCPcrypt najszybciej oblicza sumy kontrolne. Drugim powodem jest możliwość cząstkowego obliczania sumy kontrolnej (przydatne przy bardzo dużych plikach). Ilość obsługiwanych algorytmów też nie pozostała bez znaczenia.